aDriv4 website!

Linux premium73.web-hosting.com 4.18.0-553.44.1.lve.el8.x86_64 #1 SMP Thu Mar 13 14:29:12 UTC 2025 x86_64
LiteSpeed
68.65.122.244

Objects.pm

# $Id: Objects.pm,v 1.1 2003-08-18 20:20:51 matt Exp $

package XML::Parser::Style::Objects;
use strict;

sub Init {
    my $expat = shift;
    $expat->{Lists} = [];
    $expat->{Curlist} = $expat->{Tree} = [];
}

sub Start {
    my $expat   = shift;
    my $tag     = shift;
    my $newlist = [];
    my $class   = "${$expat}{Pkg}::$tag";
    my $newobj  = bless { @_, Kids => $newlist }, $class;
    push @{ $expat->{Lists} },   $expat->{Curlist};
    push @{ $expat->{Curlist} }, $newobj;
    $expat->{Curlist} = $newlist;
}

sub End {
    my $expat = shift;
    my $tag   = shift;
    $expat->{Curlist} = pop @{ $expat->{Lists} };
}

sub Char {
    my $expat = shift;
    my $text  = shift;
    my $class = "${$expat}{Pkg}::Characters";
    my $clist = $expat->{Curlist};
    my $pos   = $#$clist;

if ( $pos >= 0 and ref( $clist->[$pos] ) eq $class ) {
        $clist->[$pos]->{Text} .= $text;
    }
    else {
        push @$clist, bless { Text => $text }, $class;
    }
}

sub Final {
    my $expat = shift;
    delete $expat->{Curlist};
    delete $expat->{Lists};
    $expat->{Tree};
}

1;
__END__

=head1 NAME

XML::Parser::Style::Objects - Objects styler parser

=head1 SYNOPSIS

use XML::Parser;
  my $p = XML::Parser->new(Style => 'Objects', Pkg => 'MyNode');
  my $tree = $p->parsefile('foo.xml');

=head1 DESCRIPTION

This module implements XML::Parser's Objects style parser.

This is similar to the Tree style, except that a hash object is created for
each element. The corresponding object will be in the class whose name
is created by appending "::" and the element name to the package set with
the Pkg option. Non-markup text will be in the ::Characters class. The
contents of the corresponding object will be in an anonymous array that
is the value of the Kids property for that object.

=head1 SEE ALSO

L<XML::Parser::Style::Tree>

=cut

Name	Type	Size	Owner/Group	Permission	Last Modified	Actions
.	dir	-	root/root	0755	2024-03-03 10:17:37
..	dir	-	root/root	0755	2024-03-03 10:17:37
Debug.pm	text/plain	1 KB	root/root	0444	2019-09-24 03:18:53
Objects.pm	text/plain	1.82 KB	root/root	0444	2019-09-24 03:18:53
Stream.pm	text/plain	3.54 KB	root/root	0444	2019-09-24 03:18:53
Subs.pm	text/plain	1.12 KB	root/root	0444	2019-09-24 03:18:53
Tree.pm	text/plain	2.23 KB	root/root	0444	2023-12-28 07:45:57

For more Private tool come to me!

https://t.me/aDriv4vz